home *** CD-ROM | disk | FTP | other *** search
/ Developer CD Series 1998 August: Tool Chest / Dev.CD Aug 98 TC.toast / Tool Chest / Testing & Debugging / Virtual User / Virtual User Current Release / Tutorial / Script2.vu < prev    next >
Encoding:
Text File  |  1998-06-04  |  4.4 KB  |  138 lines  |  [TEXT/MPS ]
  1. # **********************************************************************
  2. # File:                    Script 2.vu
  3. #
  4. # Purpose:                to demonstrate screen independence,
  5. #                        matching, and list usage
  6. #
  7. # Prerequisites:        This script assumes that DrawShapesVU is the
  8. #                        currently active application on the target.
  9. #
  10. # Note:                    If an attempt is made to draw a shape and
  11. #                        the shape does not materialize, it may be
  12. #                        because the shape being drawn is smaller than 
  13. #                        DrawShapeVU's minimum shape size, not because
  14. #                        there is a problem with VU.
  15. #
  16. # Written by:            David Gaxiola
  17. #
  18. # Copyright © 1992 by Apple Computer, Inc., all rights reserved.
  19. #
  20. # **********************************************************************
  21.  
  22. # Variables here are globals; that is, they are used
  23. # throughout the script.  They begin with a lowercase g.
  24.  
  25. # variable definitions:
  26.  
  27. gToolColumn := 18;                        # relative x position
  28.                                         # inside the window
  29.                                         
  30. gToolRow := { 40,80,120,160 };            # relative y positions
  31.                                         # for tools in window
  32.                                         
  33. gWindowMod := { 41, 21, -21, -21 };        # Modify position for
  34.                                         # actual drawing space.
  35.                                         
  36. gWindowDim := { };                        # Declare empty list
  37.                                         # for window dimensions.
  38.                                         
  39. gScreenDim := { };                        # Declare empty list
  40.                                         # for screen dimensions.
  41.  
  42. # Begin main body. ***************************************************
  43.  
  44. MouseSpeed( 10 );
  45.  
  46. # Get main screen dimensions and put them into a list called
  47. # "gScreenDim".
  48. # Note the importance of using ?gScreenDim instead of
  49. # just gScreenDim. The first puts the dimensions into a
  50. # variable called gScreenDim. The second would not produce
  51. # a meaningful result.
  52.  
  53. match [ screen rectangle:?gScreenDim menubar:true ];
  54.  
  55. # Create a new work window and manually size it
  56. # to nearly the screen size.
  57. # 
  58. # Note how the regular expression /Untitled-≈/ is used 
  59. # to make the selection of the title flexible and how the
  60. # ordinal o:1 is used to denote the frontmost window.
  61.  
  62. println "# Setting up new document window.";
  63. select [ menuItem title:'New' menu:[menu title:'File' ]];
  64. Wait(2);
  65. drag [ window title:/Untitled-≈/ o:1 ] a:{ 1, 21 };
  66. size [ window title:/Untitled-≈/ o:1 ] width:( gScreenDim[3] - 2 ) 
  67.             height:( gScreenDim[4] - 22 );
  68.  
  69. # Determine and record the size of the top work window.
  70.  
  71. match [ window rectangle:?gWindowDim ordinality:1 ];
  72.  
  73. # Draw a square with random position and size,
  74. # yet still within the window bounds.
  75. # 
  76. # Note the use of the built-in task random()
  77. # as well as the use of lists in the equations.
  78.  
  79. println "# Performing square drawing operation.";
  80. move absolute:{ (gWindowDim[1] + gToolColumn), 
  81.                         (gWindowDim[2] + gToolRow[2])};
  82. click;
  83. xStart := Random( (gWindowDim[1] + gWindowMod[1]), 
  84.                         (gWindowDim[3] + gWindowMod[3]) );
  85. xStop := Random( (gWindowDim[1] + gWindowMod[1]), 
  86.                         (gWindowDim[3] + gWindowMod[3]) );
  87. yStart := Random( (gWindowDim[2] + gWindowMod[2]), 
  88.                         (gWindowDim[4] + gWindowMod[4]) );
  89. yStop := Random( (gWindowDim[2] + gWindowMod[2]), 
  90.                         (gWindowDim[4] + gWindowMod[4]) );
  91.  
  92. move absolute:{ xStart, yStart };
  93. pressMouse;
  94. Wait(1);
  95. move absolute:{ xStop, yStop };
  96. releaseMouse;
  97.  
  98. # Alter window size and update the main gWindowDim.
  99. # Note the use of the replace built-in task and of
  100. # list manipulation.
  101.  
  102. println "# Sizing window.";
  103. size [ window title:/Untitled-≈/ ordinality:1 ] rectangle:{ -40, 0 };
  104. match [ window rectangle:?tempDim ordinality:1 ];
  105. gWindowDim := replace( tempDim[3], 3, gWindowDim );
  106.  
  107. ### Draw an oval:
  108.  
  109. println "# Performing oval drawing operation.";
  110. move absolute:{ (gWindowDim[1] + gToolColumn),
  111.                         (gWindowDim[2] + gToolRow[3]) };
  112. click;
  113.  
  114. xStart := Random( (gWindowDim[1] + gWindowMod[1]), 
  115.                         (gWindowDim[3] + gWindowMod[3]) );
  116. xStop := Random( (gWindowDim[1] + gWindowMod[1]), 
  117.                         (gWindowDim[3] + gWindowMod[3]) );
  118. yStart := Random( (gWindowDim[2] + gWindowMod[2]), 
  119.                         (gWindowDim[4] + gWindowMod[4]) );
  120. yStop := Random( (gWindowDim[2] + gWindowMod[2]), 
  121.                         (gWindowDim[4] + gWindowMod[4]) );
  122.  
  123. move absolute:{ xStart, yStart };
  124. pressMouse;
  125. Wait(1);                                 # for slower targets
  126. move absolute:{ xStop, yStop };
  127. releaseMouse;
  128.  
  129. ### Discard the window when finished:
  130.  
  131. println "# Discarding window.";
  132. close [ window title:/Untitled-≈/ ordinality:1 ];
  133. Wait(1);                                 # for slower targets
  134. select [ button title:'No' window:[ window style:dialog ]];
  135.  
  136. println "# Finished";
  137. # End main body. ***************************************************
  138.